Imports System
Imports System.Collections.Generic
Imports System.Globalization
Imports System.Text

Imports Jssk.Util
Imports Jssk.CastaNet

''' <summary>
''' Wcpeクラス
'''
'''   CastaNetにアタッチする｢WCPE｣放送局のクラスです。ICNStationインターフェースを実装します。
'''
''' </summary>
''' <author>TELLA</author>
''' <version>
''' 2006/08/08 新規作成
''' 2007/09/05 修正(プロパティ追加等)
''' </version>
Public Class Wcpe : Implements ICNStation

  Private eHeaderTexts As String()

  Private eDispName As String = "WCPE"
  Private eDispInfo As String = "[WCPE] http://theclassicalstation.org/" & vbNewLine & _
                                  "WCPEはクラシック音楽放送における" & vbNewLine & _
                                  "素晴らしさに捧げられた非営利的で、" & vbNewLine & _
                                  "独立していて、リスナーによって" & vbNewLine & _
                                  "支持されたステーションです。" & vbNewLine & _
                                  "(WCPEサイトより)"
  Private eStreamUrl As String = "mms://rx-wes-sea150.rbn.com/farm/pull/tx-rbn-sea08:1259/wmtencoder/wcpe/wcpeint/wmlive/wcpewin.asf"
  Private ePlayListUrlPart As String = "http://theclassicalstation.org/music/@DayOfTheWeek@.shtml"
  Private eCodePage As Integer = Encoding.Default.CodePage ' システムデフォルト
  Private eTimeDiff As Integer = -13

  ' 日付文字列を日付に変換するためのDateTimeFormatInfo
  Dim eDtfi As DateTimeFormatInfo = New DateTimeFormatInfo()

  ' PlayListUrlが呼ばれたときに渡された日本時間に対応する現地時間の日付
  Private eDateLcl As DateTime

  ''' <summary>
  ''' コンストラクタです。
  ''' </summary>
  Sub New()

    Me.eDtfi.FullDateTimePattern = "MMMM d, yyyy" ' 例：August 8, 2006

  End Sub

#Region "// プロパティ //////////////////////////////////////////////////"

  '////////////////////////////////////////////////////////////////////////////////
  '// プロパティ
  '////////////////////////////////////////////////////////////////////////////////

  ''' <summary>
  ''' 番組表のヘッダーテキストを設定・取得します。
  ''' </summary>
  ''' <value>ヘッダーテキスト</value>
  Property HeaderTexts() As String() Implements ICNStation.HeaderTexts

    Set(ByVal value As String())
      Me.eHeaderTexts = value
    End Set
    Get
      Return Me.eHeaderTexts
    End Get

  End Property

  ''' <summary>
  ''' CastaNetの｢放送局選択｣コンボボックス等に表示する放送局名を設定・取得します。
  ''' </summary>
  ''' <value>放送局名</value>
  Property DispName() As String Implements ICNStation.DispName

    Set(ByVal value As String)
      Me.eDispName = value
    End Set
    Get
      Return Me.eDispName
    End Get

  End Property

  ''' <summary>
  ''' CastaNetの情報アイコンを指したとき等に表示される放送局の情報を設定・取得します。
  ''' </summary>
  ''' <value>放送局の情報</value>
  Property DispInfo() As String Implements ICNStation.DispInfo

    Set(ByVal value As String)
      Me.eDispInfo = value
    End Set
    Get
      Return Me.eDispInfo
    End Get

  End Property

  ''' <summary>
  ''' 放送を聴くためのストリームのURLを設定・取得します。
  ''' </summary>
  ''' <value>ストリームURL</value>
  Property StreamUrl() As String Implements ICNStation.StreamUrl

    Set(ByVal value As String)
      Me.eStreamUrl = value
    End Set
    Get
      Return Me.eStreamUrl
    End Get

  End Property

  ''' <summary>
  ''' 番組表を取得するためのURLの一部を設定・取得します。
  ''' </summary>
  ''' <value>番組表取得URLの一部</value>
  Property PlayListUrlPart() As String Implements ICNStation.PlayListUrlPart

    Set(ByVal value As String)
      Me.ePlayListUrlPart = value
    End Set
    Get
      Return Me.ePlayListUrlPart
    End Get

  End Property

  ''' <summary>
  ''' 番組表の読み込み時に指定する文字セットのWindowsコードページ値を設定・取得します。
  ''' </summary>
  ''' <value>Windowsコードページ値</value>
  Property CodePage() As Integer Implements ICNStation.CodePage

    Set(ByVal value As Integer)
      Me.eCodePage = value
    End Set
    Get
      Return Me.eCodePage
    End Get

  End Property

  ''' <summary>
  ''' 日本との時差を設定・取得します。
  ''' </summary>
  ''' <value>日本との時差(h)</value>
  Property TimeDiff() As Integer Implements ICNStation.TimeDiff

    Set(ByVal value As Integer)
      Me.eTimeDiff = value
    End Set
    Get
      Return Me.eTimeDiff
    End Get

  End Property

#End Region

#Region "// Public メソッド ////////////////////////////////////////////////////////////"

  '////////////////////////////////////////////////////////////////////////////////
  '// Public メソッド
  '////////////////////////////////////////////////////////////////////////////////

  ''' <summary>
  ''' 指定された日本時間に対応する番組表を取得するためのURLを返します。
  ''' 
  '''   ※ CastaNetから引数で渡された日本時間を適宜加工してURLを組み立てて返すことになると思います。
  '''   ※ 必要に応じてURLエンコードを行ってください。
  ''' 
  ''' </summary>
  ''' <param name="dTimeJpn">日本時間</param>
  ''' <returns>番組表取得URL</returns>
  Function PlayListUrl(ByVal dTimeJpn As DateTime) As String Implements ICNStation.PlayListUrl

    ' 指定された日本時間から現地時間を取得する
    Dim dTimeLcl As DateTime = dTimeJpn.AddHours(Me.eTimeDiff)
    ' 現地の曜日を文字列(小文字)で取得する
    Dim dow As DayOfWeek = dTimeLcl.DayOfWeek()
    Dim dowStr As String = [Enum].GetName(GetType(DayOfWeek), dow).ToLower()
    ' sunday
    ' monday
    ' tuesday
    ' wednesday
    ' thursday
    ' friday
    ' saturday

    ' このあと引き続いて呼ばれるPlayListメソッドのために現地日付を保存する
    Me.eDateLcl = dTimeLcl.Date

    Return Me.ePlayListUrlPart.Replace("@DayOfTheWeek@", dowStr)

  End Function

  ''' <summary>
  ''' 番組表を返します。
  ''' 
  '''  CastaNetがPlayListUrl()メソッドを呼び出して得たURLにアクセスし、読み込んだテキストを引数で渡します。
  ''' 
  '''  必要な情報が１回で取得できないときは、第３引数のnextUrlに次のURLを渡したうえで、Nothingを返してください。
  '''  CastaNetはそのURLにアクセスして情報を取得し、再度第１引数に渡してこのメソッドを呼び出します。
  '''  何回目の呼び出しかは第２引数で知ることができます。
  '''  最終的に必要な情報がそろったら、下記のようなリストを作成して返してください。
  '''
  '''  番組表は、以下の項目順で格納された文字列配列をList(Of String())に格納して返してください。
  ''' 
  '''   +----------+--------+--------+--------+--------+-----------------+
  '''   |   (0)    |  (1)   |  (2)   |  (3)   |  (4)   |       (5)       |
  '''   +----------+--------+--------+--------+--------+-----------------+
  '''   | 現地時刻 | 作曲者 |  曲名  | 演奏者 | CD番号 | CD購入サイトURL |
  '''   +----------+--------+--------+--------+--------+-----------------+
  ''' 
  '''   ※ ｢現地時刻｣はDateTimeに変換できる正しい文字列をセットしてください。
  '''   ※ ｢現地時刻｣は時刻部分だけをセットしてください。(例："12:01 am")
  '''   ※ 情報の無い項目にはNothingをセットしてください。
  '''   ※ 各レコードの格納順は自由です。時間等でソートされている必要はありません。
  '''   ※ HTMLデコードはCastaNet本体側で行いますので、実装クラスでは特に必要ありません。
  '''
  ''' </summary>
  ''' <param name="playListText">番組表の情報を含んだテキスト</param>
  ''' <param name="callCount"   >CastaNetからこのメソッドが呼ばれた回数、最初は０</param>
  ''' <param name="nextUrl"     >次の情報の取得先URL</param>
  ''' <returns>番組表を格納したList、取得できなかったときは要素数を0にして返す、さらに情報が欲しいときはNothingを返す</returns>
  Function PlayList(ByVal playListText As String, ByVal callCount As Integer, ByRef nextUrl As String) As List(Of String()) Implements ICNStation.PlayList

    ' 番組表を格納するListを用意する
    Dim playList_ As List(Of String()) = New List(Of String())()

    ' 渡されたテキストから日付部分を取り出す(例：August 8, 2006)
    Dim dTimeLclStr As String = ComUtil.GetSubstring(playListText, "<span class=""date"">", ":</span>", 0)
    ' 日付文字列から日付に変換する
    Dim dateLcl As DateTime = Convert.ToDateTime(dTimeLclStr, Me.eDtfi)
    ' 直前に呼ばれたPlayListUrlメソッドで保存した現地日付と異なる場合はここで戻る
    If dateLcl <> Me.eDateLcl Then Return playList_


    ' 曲目リストが含まれている部分を取り出す
    Dim tuneList As String = ComUtil.GetSubstring(playListText, "</TABLE>", "</table>", 0)

    ' すべての<tr>タグについて繰り返す
    Dim idx As Integer = 0
    Do
      ' @@ 各種情報を取り出す @@
      ' 曲情報全体
      Dim tuneInfo As String = ComUtil.GetSubstring(tuneList, "<tr>", "</tr>", idx, idx)
      If tuneInfo Is Nothing Then Exit Do
      ' 番組表の１レコードの一次元配列を作成する
      Dim playListArran(5) As String
      ' すべての<td>タグについて繰り返す
      Dim cdNo As String = String.Empty
      Dim idx2 As Integer = 0
      Dim itemIdx As Integer = 0
      Do While itemIdx < 8
        Dim item As String = ComUtil.GetSubstring(tuneInfo, "<td>", "</td>", idx2, idx2)
        Select Case itemIdx
          Case 0
            ' とばし
          Case 1
            ' 放送時刻
            playListArran(0) = item
          Case 2
            ' CDサイトURL
            Dim cdUrl As String = ComUtil.GetSubstring(item, "<a href=""", """ target=", 0)
            playListArran(5) = cdUrl
          Case 3
            ' 作曲者
            playListArran(1) = item
          Case 4
            ' 曲名
            playListArran(2) = item
          Case 5
            ' 演奏者
            playListArran(3) = item
          Case 6
            ' CD番号(メーカー)
            cdNo = item
          Case 7
            ' CD番号(No)
            playListArran(4) = cdNo & ": " & item
        End Select
        ' インデックスをインクリメントする
        itemIdx = itemIdx + 1
      Loop
      ' 配列をListに追加する
      playList_.Add(playListArran)
    Loop

    Return playList_

  End Function

  ''' <summary>
  ''' 任意情報を受け取ります。
  ''' 
  '''  CastaNetは、各放送局の設定ファイルの [COption]Info キーに設定されている文字列を
  '''  このメソッドを呼び出して実装クラスに渡します。
  '''  このメソッドは、CastaNetが実装クラスのインスタンスを生成した直後に呼び出します。
  '''  
  '''  任意情報の使用目的や書式などは、このインターフェースの実装者が自由に決めてください。
  ''' 
  ''' </summary>
  ''' <param name="info">情報の文字列</param>
  Sub OptionInfo(ByVal info As String) Implements ICNStation.OptionInfo

    ' 現バージョンでは実装なし

  End Sub

#End Region


End Class